      SUBROUTINE SETDLM (ITYPE,CSTRNG,IBEG,NUMB,ITBL)
C
C      SET DELIMITERS IS USED IN CONJUNCTION WITH SUBROUTINE
C     FINDLM, AND SETS DELIMITERS IN THREE TYPES:
C         TYPE 1 - NORMAL DELIMS, SUCH AS A COMMA
C         TYPE 2 - "BLANK" TYPE DELIM
C         TYPE 3 - STRING TYPE DELIMS, ENCLOSED IN QUOTES (IGNORES
C                  ALL DELIMS INSIDE OF STRING)
C         SEE DOCUMENTATION FOR FURTHER EXPLAINATION
C
C         ITYPE - SET DELIM TYPE 1, 2, OR 3 (AS ABOVE)
C         CSTRNG - CHARACTER STRING CONTAINING DELIMS TO BE SET
C         IBEG - CHAR POSITION IN CSTRNG AT WHICH TO BEGIN TO SET
C         NUMB - NUMBER OF DELIMS TO BE SET (IN ITYPE)
C
C     SETDLM WILL BE CALLED BY FINDLM TO SET DEFAULT VALUES IF
C     NOT CALLED BY USER
C
      DIMENSION ILIST(3)
      CHARACTER CDS(3)*6, CSTRNG*(*)
      INTEGER ITBL(-1:126)
C
C     DEFAULT DELIMITER VALUES
C
      DATA ILIST /6,1,2/
C
C
      IF (ITBL(-1).NE.-7456) THEN
      DO 5 I=0,126
      ITBL(I) = 1
 5    CONTINUE
      ITBL(-1) = -7456
      CDS(1)(1:1) = ','
      CDS(1)(2:2) = '='
      CDS(1)(3:3) = '/'
      CDS(1)(4:4) = '>'
      CDS(1)(5:5) = '('
      CDS(1)(6:6) = ')'
      CDS(2)(1:1) = ' '
      CDS(3)(1:1) = CHAR (34)                                           HPIMLlg
      CDS(3)(2:2) = CHAR (39)                                           HPIMLlg
C     CDS(3)(1:1) = CHAR (127)                                          A
C     CDS(3)(2:2) = CHAR (125)                                          A
      ENDIF
C
C     WHEN ITYPE = 0, RESET ALL DELIMS TO DEFAULT VALUES
C
      IF (ITYPE.EQ.0) THEN
          DO 1010 J=1,3
          CALL CHDLM (J,CDS(J),1,ILIST(J),ITBL)
 1010 CONTINUE
C
C     IF NUMB < 0, THEN SET ITYPE DELIMS TO DEFAULT VALUES
C
      ELSE IF (NUMB.LT.0) THEN
          CALL CHDLM (ITYPE,CDS(ITYPE),1,ILIST(ITYPE),ITBL)
      ELSE
C
C     OTHERWISE, CHANGE DELIM VALUES AS DESIRED
C
      CALL CHDLM (ITYPE, CSTRNG,IBEG,NUMB,ITBL)
      END IF
      RETURN
      END
