      SUBROUTINE QEFTCL
     I                  (MESSFL)
C
C     + + + PURPOSE + + +
C     edit temperature and climatalogical functional parameters
C
C     + + + DUMMY ARGUMENTS + + ++ 
      INTEGER   MESSFL
C
C     + + + ARGUMENT DEFINITIONS + + +
C     MESSFL - Fortran unit number for message file
C
C     + + + COMMON BLOCKS + + +
      INCLUDE 'CQ2VAL.INC'
C
C     + + + LOCAL VARIABLES + + +
      INTEGER      I1,SCLU,SGRP,RESP,RNUM,IRET,
     1             IVAL(1,MXRCH),CVAL(1,3,MXRCH)
      DOUBLE PRECISION DVAL(1)
      CHARACTER*1  TBUFF(80,MXRCH)
      CHARACTER*16 SCNAME
C
C     + + + INTRINSICS + + +
      INTRINSIC    ABS
C
C     + + + EXTERNALS + + +
      EXTERNAL     QRESP, QRESPM, QRESCN, QEINCO, QETHET, ZGTRET
C
C     + + + END SPECIFICATIONS + + +
C
      I1  = 1
      SCLU= 13
C
 5    CONTINUE
C
        SGRP= 1
        CALL QRESP (MESSFL,SCLU,SGRP,RESP)
C
        GO TO (10,20,30,40,50),RESP
C
 10     CONTINUE
C         geographical data
          RNUM= 8
          SGRP= 2+ METFLG
          CALL QRESCD (MESSFL,SCLU,SGRP,I1,RNUM,I1,I1,I1,I1,
     M                 IVAL,PCRVL(5),DVAL,CVAL,TBUFF)
          GO TO 100
C
 20     CONTINUE
C         climatological data
          IF (NPOPT(4).EQ.1) THEN
C           which type of climate data (5A or LOCAL CLIM)
            IF (ABS(CLDAT(1,1)-1.).LT.1.0E-5) THEN
C             currently using local climate card
              RESP= 1
            ELSE
C             currently using data 5a card
              RESP= 2
            END IF
            SGRP= 7
            CALL QRESP (MESSFL,SCLU,SGRP,RESP)
C           get user exit command
            CALL ZGTRET(IRET)
            IF (IRET.EQ.1) THEN
C             user selected an option, not 'prev' screen
              IF (RESP.EQ.1) THEN
C               local climatology card
                SGRP= 8+ METFLG
                RNUM= 5
                CALL QRESPM (MESSFL,SCLU,SGRP,I1,RNUM,I1,
     M                       IVAL,CLDAT(2,1),CVAL,TBUFF)
C               indicate Local Clim will be used
                CLDAT(1,1)= 1
              ELSE
C               group data5a, form 8a
                DO 25 I= 1,NUMRCH
                  DAT5A(1,I)= DAT2(1,I)
 25             CONTINUE
                RNUM= 8
                SGRP= 4+ METFLG
                CALL QRESCN (MESSFL,SCLU,SGRP,I1,RNUM,I1,NUMRCH,I1,
     M                       IVAL,DAT5A,CVAL,TBUFF)
C               indicate Local Clim will not be used
                CLDAT(1,1)= -999.
              END IF
            END IF
          END IF
          GO TO 100
C
 30     CONTINUE
C         Theta values, data type 1B
          SCNAME= 'Theta (EFTT)'
          CALL QETHET (MESSFL,SCNAME,
     M                 THEIND,THEVAL)
          GO TO 100
C
 40     CONTINUE
C         initial conditions
          SCNAME= 'Initial-1 (EFTI)'
          DO 45 I= 1,NUMRCH
            DAT7(1,I) = DAT2(1,I)
            DAT7A(1,I)= DAT2(1,I)
 45       CONTINUE
          CALL QEINCO (MESSFL,NUMRCH,METFLG,SCNAME,
     M                 DAT7,DAT7A)
          GO TO 100
C
 50     CONTINUE
C         all done
          GO TO 100
C
 100    CONTINUE
C
      IF (RESP.NE.5) GO TO 5
C
      RETURN
      END
